LearnOpenGL

Geometry-Shader.html (28078B)

---

     <div id="content">
     <h1 id="content-title">Geometry Shader</h1>
 <h1 id="content-url" style='display:none;'>Advanced-OpenGL/Geometry-Shader</h1>
 <p>
   Between the vertex and the fragment shader there is an optional shader stage called the <def>geometry shader</def>. A geometry shader takes as input a set of vertices that form a single primitive e.g. a point or a triangle. The geometry shader can then transform these vertices as it sees fit before sending them to the next shader stage. What makes the geometry shader interesting is that it is able to convert the original primitive (set of vertices) to completely different primitives, possibly generating more vertices than were initially given. 
 </p>
 
 <p>
   We're going to throw you right into the deep by showing you an example of a geometry shader:
 </p>
 
 <pre><code>
 #version 330 core
 layout (points) in;
 layout (line_strip, max_vertices = 2) out;
 
 void main() {    
     gl_Position = gl_in[0].gl_Position + vec4(-0.1, 0.0, 0.0, 0.0); 
     EmitVertex();
 
     gl_Position = gl_in[0].gl_Position + vec4( 0.1, 0.0, 0.0, 0.0);
     EmitVertex();
     
     EndPrimitive();
 }  
 </code></pre>
 
 <p>
   At the start of a geometry shader we need to declare the type of primitive input we're receiving from the vertex shader. We do this by declaring a layout specifier in front of the <fun>in</fun> keyword. This input layout qualifier can take any of the following primitive values:
 </p>
 
 <ul>
   <li><code>points</code>: when drawing <var>GL_POINTS</var> primitives (<code>1</code>).</li>
   <li><code>lines</code>: when drawing <var>GL_LINES</var> or <var>GL_LINE_STRIP</var> (<code>2</code>).</li>
   <li><code>lines_adjacency</code>: <var>GL_LINES_ADJACENCY</var> or <var>GL_LINE_STRIP_ADJACENCY</var> (<code>4</code>).</li>
   <li><code>triangles</code>: <var>GL_TRIANGLES</var>, <var>GL_TRIANGLE_STRIP</var> or <var>GL_TRIANGLE_FAN</var> (<code>3</code>).</li>
    <li><code>triangles_adjacency </code>: <var>GL_TRIANGLES_ADJACENCY</var> or <var>GL_TRIANGLE_STRIP_ADJACENCY </var> (<code>6</code>).</li>
 </ul>
 
 <p>
   These are almost all the rendering primitives we're able to give to rendering calls like <fun><function id='1'>glDrawArrays</function></fun>. If we'd chosen to draw vertices as <var>GL_TRIANGLES</var> we should set the input qualifier to <code>triangles</code>. The number within the parenthesis represents the minimal number of vertices a single primitive contains.
 </p>
 
 <p>
   We also need to specify a primitive type that the geometry shader will output and we do this via a layout specifier in front of the <fun>out</fun> keyword. Like the input layout qualifier, the output layout qualifier can take several primitive values:
 </p>
 
 <ul>
   <li><code>points</code></li>
   <li><code>line_strip</code></li>
   <li><code>triangle_strip</code></li>
 </ul>
 
 <p>
 	With just these 3 output specifiers we can create almost any shape we want from the input primitives. To generate a single triangle for example we'd specify <code>triangle_strip</code> as the output and output 3 vertices.
 </p>
 
 <p>
   The geometry shader also expects us to set a maximum number of vertices it outputs (if you exceed this number, OpenGL won't draw the <em>extra</em> vertices) which we can also do within the layout qualifier of the <fun>out</fun> keyword. In this particular case we're going to output a <code>line_strip</code> with a maximum number of 2 vertices. 
 </p>
 
 <note>
   In case you're wondering what a line strip is: a line strip binds together a set of points to form one continuous line between them with a minimum of 2 points. Each extra point results in a new line between the new point and the previous point as you can see in the following image with 5 point vertices:
 
 <img src="/img/advanced/geometry_shader_line_strip.png" class="clean" alt="Image of line_strip primitive in geometry shader"/>
 </note>
 
 <p>
   To generate meaningful results we need some way to retrieve the output from the previous shader stage. GLSL gives us a <def>built-in</def> variable called <fun>gl_in</fun> that internally (probably) looks something like this:
 </p>
 
 <pre><code>
 in gl_Vertex
 {
     vec4  gl_Position;
     float gl_PointSize;
     float gl_ClipDistance[];
 } gl_in[];  
 </code></pre>
 
 <p>
   Here it is declared as an <def>interface block</def> (as discussed in the <a href="https://learnopengl.com/Advanced-OpenGL/Advanced-GLSL" target="_blank">previous</a> chapter) that contains a few interesting variables of which the most interesting one is <var>gl_Position</var> that contains the vector we set as the vertex shader's output.
 </p>
 
 <p>
   Note that it is declared as an array, because most render primitives contain more than 1 vertex. The geometry shader receives <strong>all</strong> vertices of a primitive as its input.
 </p>
 
 <p>
   Using the vertex data from the vertex shader stage we can generate new data with 2 geometry shader functions called <fun>EmitVertex</fun> and <fun>EndPrimitive</fun>. The geometry shader expects you to generate/output at least one of the primitives you specified as output. In our case we want to at least generate one line strip primitive.
 </p>
 
 <pre><code>
 #version 330 core
 layout (points) in;
 layout (line_strip, max_vertices = 2) out;
   
 void main() {    
     gl_Position = gl_in[0].gl_Position + vec4(-0.1, 0.0, 0.0, 0.0); 
     EmitVertex();
 
     gl_Position = gl_in[0].gl_Position + vec4( 0.1, 0.0, 0.0, 0.0);
     EmitVertex();
     
     EndPrimitive();
 }    
 </code></pre>
 
 <p>
   Each time we call <fun>EmitVertex</fun>, the vector currently set to <var>gl_Position</var> is added to the output primitive. Whenever <fun>EndPrimitive</fun> is called, all emitted vertices for this primitive are combined into the specified output render primitive. By repeatedly calling <fun>EndPrimitive</fun>, after one or more <fun>EmitVertex</fun> calls, multiple primitives can be generated. This particular case emits two vertices that were translated by a small offset from the original vertex position and then calls <fun>EndPrimitive</fun>, combining the two vertices into a single line strip of 2 vertices.
 </p>
 
 <p>
   Now that you (sort of) know how geometry shaders work you can probably guess what this geometry shader does. This geometry shader takes a point primitive as its input and creates a horizontal line primitive with the input point at its center. If we were to render this it looks something like this:
 </p>
 
 <img src="/img/advanced/geometry_shader_lines.png" class="clean" alt="Geometry shader drawing lines out of points in OpenGL"/>
 
 <p>
   Not very impressive yet, but it's interesting to consider that this output was generated using just the following render call:
 </p>
 
 <pre class="cpp"><code>
 <function id='1'>glDrawArrays</function>(GL_POINTS, 0, 4);  
 </code></pre>
 
 <p>
   While this is a relatively simple example, it does show you how we can use geometry shaders to (dynamically) generate new shapes on the fly. Later in this chapter we'll discuss a few interesting effects that we can create using geometry shaders, but for now we're going to start with a simple example.
 </p>
 
 <h2>Using geometry shaders</h2>
 <p>
   To demonstrate the use of a geometry shader we're going to render a really simple scene where we draw 4 points on the z-plane in normalized device coordinates. The coordinates of the points are:
 </p>
 
 <pre><code>
 float points[] = {
 	-0.5f,  0.5f, // top-left
 	 0.5f,  0.5f, // top-right
 	 0.5f, -0.5f, // bottom-right
 	-0.5f, -0.5f  // bottom-left
 };  
 </code></pre>
 
 <p>
   The vertex shader needs to draw the points on the z-plane so we'll create a basic vertex shader:
 </p>
 
 <pre><code>
 #version 330 core
 layout (location = 0) in vec2 aPos;
 
 void main()
 {
     gl_Position = vec4(aPos.x, aPos.y, 0.0, 1.0); 
 }
 </code></pre>
 
 <p>
   And we'll output the color green for all points which we code directly in the fragment shader:
 </p>
 
 <pre><code>
 #version 330 core
 out vec4 FragColor;
 
 void main()
 {
     FragColor = vec4(0.0, 1.0, 0.0, 1.0);   
 }  
 </code></pre>
 
 <p>
   Generate a VAO and a VBO for the points' vertex data and then draw them via <fun><function id='1'>glDrawArrays</function></fun>:
 </p>
 
 <pre class="cpp"><code>
 shader.use();
 <function id='27'>glBindVertexArray</function>(VAO);
 <function id='1'>glDrawArrays</function>(GL_POINTS, 0, 4); 
 </code></pre>
 
 <p>
   The result is a dark scene with 4 (difficult to see) green points:
 </p>
 
 <img src="/img/advanced/geometry_shader_points.png" class="clean" alt="4 Points drawn using OpenGL"/>
 
 <p>
   But didn't we already learn to do all this? Yes, and now we're going to spice this little scene up by adding geometry shader magic to the scene.
 </p>
 
 <p>
   For learning purposes we're first going to create what is called a <def>pass-through</def> geometry shader that takes a point primitive as its input and <em>passes</em> it to the next shader unmodified:
 </p>
 
 <pre><code>
 #version 330 core
 layout (points) in;
 layout (points, max_vertices = 1) out;
 
 void main() {    
     gl_Position = gl_in[0].gl_Position; 
     EmitVertex();
     EndPrimitive();
 }  
 </code></pre>
 
 <p>
   By now this geometry shader should be fairly easy to understand. It simply emits the unmodified vertex position it received as input and generates a point primitive.
 </p>
 
 <p>
   A geometry shader needs to be compiled and linked to a program just like the vertex and fragment shader, but this time we'll create the shader using <var>GL_GEOMETRY_SHADER</var> as the shader type:
 </p>
 
 <pre class="cpp"><code>
 geometryShader = <function id='37'>glCreateShader</function>(GL_GEOMETRY_SHADER);
 <function id='42'>glShaderSource</function>(geometryShader, 1, &gShaderCode, NULL);
 <function id='38'>glCompileShader</function>(geometryShader);  
 [...]
 <function id='34'>glAttachShader</function>(program, geometryShader);
 <function id='35'>glLinkProgram</function>(program);  
 </code></pre>
 
 <p>
   The shader compilation code is the same as the vertex and fragment shaders. Be sure to check for compile or linking errors!
 </p>
 
 <p>
   If you'd now compile and run you should be looking at a result that looks a bit like this:
 </p>
 
 <img src="/img/advanced/geometry_shader_points.png" class="clean" alt="4 Points drawn using OpenGL (with geometry shader this time!)"/>
 
 <p>
   It's exactly the same as without the geometry shader! It's a bit dull, I'll admit that, but the fact that we were still able to draw the points means that the geometry shader works, so now it's time for the more funky stuff!
 </p>
 
 <h2>Let's build houses</h2>
 <p>
   Drawing points and lines isn't <strong>that</strong> interesting so we're going to get a little creative by using the geometry shader to draw a house for us at the location of each point. We can accomplish this by setting the output of the geometry shader to <def>triangle_strip</def> and draw a total of three triangles: two for the square house and one for the roof.
 </p>
 
 <p>
   A triangle strip in OpenGL is a more efficient way to draw triangles with fewer vertices. After the first triangle is drawn, each subsequent vertex generates another triangle next to the first triangle: every 3 adjacent vertices will form a triangle. If we have a total of 6 vertices that form a triangle strip we'd get the following triangles: (1,2,3), (2,3,4), (3,4,5) and (4,5,6); forming a total of 4 triangles. A triangle strip needs at least 3 vertices and will generate N-2 triangles; with 6 vertices we created 6-2 = 4 triangles. The following image illustrates this:
 </p>
 
 <img src="/img/advanced/geometry_shader_triangle_strip.png" class="clean" alt="Image of a triangle strip with their index order in OpenGL"/>
 
 <p>
   Using a triangle strip as the output of the geometry shader we can easily create the house shape we're after by generating 3 adjacent triangles in the correct order. The following image shows in what order we need to draw what vertices to get the triangles we need with the blue dot being the input point:
 </p>
 
 <img src="/img/advanced/geometry_shader_house.png" class="clean" alt="How a house figure should be drawn from a single point using geometry shaders"/>
 
 <p>
   This translates to the following geometry shader:
 </p>
 
 <pre><code>
 #version 330 core
 layout (points) in;
 layout (triangle_strip, max_vertices = 5) out;
 
 void build_house(vec4 position)
 {    
     gl_Position = position + vec4(-0.2, -0.2, 0.0, 0.0);    // 1:bottom-left
     EmitVertex();   
     gl_Position = position + vec4( 0.2, -0.2, 0.0, 0.0);    // 2:bottom-right
     EmitVertex();
     gl_Position = position + vec4(-0.2,  0.2, 0.0, 0.0);    // 3:top-left
     EmitVertex();
     gl_Position = position + vec4( 0.2,  0.2, 0.0, 0.0);    // 4:top-right
     EmitVertex();
     gl_Position = position + vec4( 0.0,  0.4, 0.0, 0.0);    // 5:top
     EmitVertex();
     EndPrimitive();
 }
 
 void main() {    
     build_house(gl_in[0].gl_Position);
 }  
 </code></pre>
 
 <p>
   This geometry shader generates 5 vertices, with each vertex being the point's position plus an offset to form one large triangle strip. The resulting primitive is then rasterized and the fragment shader runs on the entire triangle strip, resulting in a green house for each point we've rendered:
 </p>
 
 <img src="/img/advanced/geometry_shader_houses.png" class="clean" alt="Houses drawn with points using geometry shader in OpenGL"/>
 
 <p>
   You can see that each house indeed consists of 3 triangles - all drawn using a single point in space. The green houses do look a bit boring though, so let's liven it up a bit by giving each house a unique color. To do this we're going to add an extra vertex attribute in the vertex shader with color information per vertex and direct it to the geometry shader that further forwards it to the fragment shader. 
 </p>
 
 <p>
   The updated vertex data is given below:
 </p>
 
 <pre><code>
 float points[] = {
     -0.5f,  0.5f, 1.0f, 0.0f, 0.0f, // top-left
      0.5f,  0.5f, 0.0f, 1.0f, 0.0f, // top-right
      0.5f, -0.5f, 0.0f, 0.0f, 1.0f, // bottom-right
     -0.5f, -0.5f, 1.0f, 1.0f, 0.0f  // bottom-left
 };  
 </code></pre>
 
 <p>
   Then we update the vertex shader to forward the color attribute to the geometry shader using an interface block:
 </p>
 
 <pre><code>
 #version 330 core
 layout (location = 0) in vec2 aPos;
 layout (location = 1) in vec3 aColor;
 
 out VS_OUT {
     vec3 color;
 } vs_out;
 
 void main()
 {
     gl_Position = vec4(aPos.x, aPos.y, 0.0, 1.0); 
     vs_out.color = aColor;
 }  
 </code></pre>
 
 <p>
   Then we also need to declare the same interface block (with a different interface name) in the geometry shader:
 </p>
 
 <pre><code>
 in VS_OUT {
     vec3 color;
 } gs_in[];  
 </code></pre>
 
 <p>
   Because the geometry shader acts on a set of vertices as its input, its input data from the vertex shader is always represented as arrays of vertex data even though we only have a single vertex right now.
 </p>
 
 <note>
   We don't necessarily have to use interface blocks to transfer data to the geometry shader. We could have also written it as:
 <pre><code>
 in vec3 outColor[];
 </code></pre>
   This works if the vertex shader forwarded the color vector as <code>out</code> <code>vec3</code> <code>outColor</code>. However, interface blocks are easier to work with in shaders like the geometry shader. In practice, geometry shader inputs can get quite large and grouping them in one large interface block array makes a lot more sense.  
 </note>
 
 <p>
   We should also declare an output color vector for the next fragment shader stage:
 </p>
 
 <pre><code>
 out vec3 fColor;  
 </code></pre>
 
 <p>
   Because the fragment shader expects only a single (interpolated) color it doesn't make sense to forward multiple colors. The <var>fColor</var> vector is thus not an array, but a single vector. When emitting a vertex, that vertex will store the last stored value in <var>fColor</var> as that vertex's output value. For the houses, we can fill <var>fColor</var> once with the color from the vertex shader before the first vertex is emitted to color the entire house:
 </p>
 
 <pre><code>
 fColor = gs_in[0].color; // gs_in[0] since there's only one input vertex
 gl_Position = position + vec4(-0.2, -0.2, 0.0, 0.0);    // 1:bottom-left   
 EmitVertex();   
 gl_Position = position + vec4( 0.2, -0.2, 0.0, 0.0);    // 2:bottom-right
 EmitVertex();
 gl_Position = position + vec4(-0.2,  0.2, 0.0, 0.0);    // 3:top-left
 EmitVertex();
 gl_Position = position + vec4( 0.2,  0.2, 0.0, 0.0);    // 4:top-right
 EmitVertex();
 gl_Position = position + vec4( 0.0,  0.4, 0.0, 0.0);    // 5:top
 EmitVertex();
 EndPrimitive();  
 </code></pre>
 
 <p>
   All the emitted vertices will have the last stored value in <var>fColor</var> embedded into their data, which is equal to the input vertex's color as we defined in its attributes. All the houses will now have a color of their own:
 </p>
 
 <img src="/img/advanced/geometry_shader_houses_colored.png" class="clean" alt="Colored houses, generating using points with geometry shaders in OpenGL"/>
 
 <p>
   Just for fun we could also pretend it's winter and give their roofs a little snow by giving the last vertex a color of its own: 
 </p>
 
 <pre><code>
 fColor = gs_in[0].color; 
 gl_Position = position + vec4(-0.2, -0.2, 0.0, 0.0);    // 1:bottom-left   
 EmitVertex();   
 gl_Position = position + vec4( 0.2, -0.2, 0.0, 0.0);    // 2:bottom-right
 EmitVertex();
 gl_Position = position + vec4(-0.2,  0.2, 0.0, 0.0);    // 3:top-left
 EmitVertex();
 gl_Position = position + vec4( 0.2,  0.2, 0.0, 0.0);    // 4:top-right
 EmitVertex();
 gl_Position = position + vec4( 0.0,  0.4, 0.0, 0.0);    // 5:top
 fColor = vec3(1.0, 1.0, 1.0);
 EmitVertex();
 EndPrimitive();  
 </code></pre>
 
 <p>
   The result now looks something like this:
 </p>
 
 <img src="/img/advanced/geometry_shader_houses_snow.png" class="clean" alt="Snow-colored houses, generating using points with geometry shaders in OpenGL"/>
 
 <p>
   You can compare your source code with the OpenGL code <a href="/code_viewer_gh.php?code=src/4.advanced_opengl/9.1.geometry_shader_houses/geometry_shader_houses.cpp" target="_blank">here</a>.
 </p>
 
 <p>
   You can see that with geometry shaders you can get pretty creative, even with the simplest primitives. Because the shapes are generated dynamically on the ultra-fast hardware of your GPU this can be a lot more powerful than defining these shapes yourself within vertex buffers. Geometry shaders are a great tool for simple (often-repeating) shapes, like cubes in a voxel world or grass leaves on a large outdoor field.
 </p>
 
 <h1>Exploding objects</h1>
 <p>
   While drawing houses is fun and all, it's not something we're going to use that much. That's why we're now going to take it up one notch and explode objects! That is something we're also probably not going to use that much either, but it's definitely fun to do!
 </p>
 
 <p>
   When we say <em>exploding</em> an object we're not actually going to blow up our precious bundled sets of vertices, but we're going to move each triangle along the direction of their normal vector over a small period of time. The effect is that the entire object's triangles seem to <em>explode</em>. The effect of exploding triangles on the backpack model looks a bit like this:
 </p>
 
 <img src="/img/advanced/geometry_shader_explosion.png" class="clean" alt="Explosion effect with geometry shaders in OpenGL"/>
 
 <p>
   The great thing about such a geometry shader effect is that it works on all objects, regardless of their complexity.
 </p>
 
 <p>
   Because we're going to translate each vertex into the direction of the triangle's normal vector we first need to calculate this normal vector. What we need to do is calculate a vector that is perpendicular to the surface of a triangle, using just the 3 vertices we have access to. You may remember from the <a href="https://learnopengl.com/Getting-started/Transformations" target="_blank">transformations</a> chapter that we can retrieve a vector perpendicular to two other vectors using the <def>cross product</def>. If we were to retrieve two vectors <var>a</var> and <var>b</var> that are parallel to the surface of a triangle we can retrieve its normal vector by doing a cross product on those vectors. The following geometry shader function does exactly this to retrieve the normal vector using 3 input vertex coordinates:
 </p>
 
 <pre><code>
 vec3 GetNormal()
 {
    vec3 a = vec3(gl_in[0].gl_Position) - vec3(gl_in[1].gl_Position);
    vec3 b = vec3(gl_in[2].gl_Position) - vec3(gl_in[1].gl_Position);
    return normalize(cross(a, b));
 }  
 </code></pre>
 
 <p>
   Here we retrieve two vectors <var>a</var> and <var>b</var> that are parallel to the surface of the triangle using vector subtraction. Subtracting two vectors from each other results in a vector that is the difference of the two vectors. Since all 3 points lie on the triangle plane, subtracting any of its vectors from each other results in a vector parallel to the plane. Do note that if we switched <var>a</var> and <var>b</var> in the <fun>cross</fun> function we'd get a normal vector that points in the opposite direction - order is important here!
 </p>
 
 <p>
   Now that we know how to calculate a normal vector we can create an <fun>explode</fun> function that takes this normal vector along with a vertex position vector. The function returns a new vector that translates the position vector along the direction of the normal vector:
 </p>
 
 <pre><code>
 vec4 explode(vec4 position, vec3 normal)
 {
     float magnitude = 2.0;
     vec3 direction = normal * ((sin(time) + 1.0) / 2.0) * magnitude; 
     return position + vec4(direction, 0.0);
 } 
 </code></pre>
 
 <p>
   The function itself shouldn't be too complicated. The <fun>sin</fun> function receives a <var>time</var> uniform variable as its argument that, based on the time, returns a value between <code>-1.0</code> and <code>1.0</code>. Because we don't want to <em>implode</em> the object we transform the sin value to the <code>[0,1]</code> range. The resulting value is then used to scale the <var>normal</var> vector and the resulting <var>direction</var> vector is added to the position vector.
 </p>
 
 <p>
   The complete geometry shader for the <def>explode</def> effect, while drawing a model loaded using our <a href="https://learnopengl.com/Model-Loading/Assimp" target="_blank">model loader</a>, looks a bit like this:
 </p>
 
 <pre><code>
 #version 330 core
 layout (triangles) in;
 layout (triangle_strip, max_vertices = 3) out;
 
 in VS_OUT {
     vec2 texCoords;
 } gs_in[];
 
 out vec2 TexCoords; 
 
 uniform float time;
 
 vec4 explode(vec4 position, vec3 normal) { ... }
 
 vec3 GetNormal() { ... }
 
 void main() {    
     vec3 normal = GetNormal();
 
     gl_Position = explode(gl_in[0].gl_Position, normal);
     TexCoords = gs_in[0].texCoords;
     EmitVertex();
     gl_Position = explode(gl_in[1].gl_Position, normal);
     TexCoords = gs_in[1].texCoords;
     EmitVertex();
     gl_Position = explode(gl_in[2].gl_Position, normal);
     TexCoords = gs_in[2].texCoords;
     EmitVertex();
     EndPrimitive();
 }  
 </code></pre>
 
 <p>
   Note that we're also outputting the appropriate texture coordinates before emitting a vertex. 
 </p>
 
 <p>
   Also don't forget to actually set the <var>time</var> uniform in your OpenGL code:
 </p>
 
 <pre><code>
 shader.setFloat("time", <function id='47'>glfwGetTime</function>());  
 </code></pre>
 
 <p>
   The result is a 3D model that seems to continually explode its vertices over time after which it returns to normal again. Although not exactly super useful, it does show you a more advanced use of the geometry shader. You can compare your source code with the complete source code <a href="/code_viewer_gh.php?code=src/4.advanced_opengl/9.2.geometry_shader_exploding/geometry_shader_exploding.cpp" target="_blank">here</a>.
 </p>
 
 <h1>Visualizing normal vectors</h1>
 <p>
   To shake things up we're going to now discuss an example of using the geometry shader that is actually useful: visualizing the normal vectors of any object. When programming lighting shaders you will eventually run into weird visual outputs of which the cause is hard to determine. A common cause of lighting errors is incorrect normal vectors. Either caused by incorrectly loading vertex data, improperly specifying them as vertex attributes, or by incorrectly managing them in the shaders. What we want is some way to detect if the normal vectors we supplied are correct. A great way to determine if your normal vectors are correct is by visualizing them, and it just so happens that the geometry shader is an extremely useful tool for this purpose.
 </p>
 
 <p>
   The idea is as follows: we first draw the scene as normal without a geometry shader and then we draw the scene a second time, but this time only displaying normal vectors that we generate via a geometry shader. The geometry shader takes as input a triangle primitive and generates 3 lines from them in the directions of their normal - one normal vector for each vertex. In code it'll look something like this:
 </p>
 
 <pre><code>
 shader.use();
 DrawScene();
 normalDisplayShader.use();
 DrawScene();
 </code></pre>
 
 <p>
   This time we're creating a geometry shader that uses the vertex normals supplied by the model instead of generating it ourself. To accommodate for scaling and rotations (due to the view and model matrix) we'll transform the normals with a normal matrix. The geometry shader receives its position vectors as view-space coordinates so we should also transform the normal vectors to the same space. This can all be done in the vertex shader:
 </p>
 
 <pre><code>
 #version 330 core
 layout (location = 0) in vec3 aPos;
 layout (location = 1) in vec3 aNormal;
 
 out VS_OUT {
     vec3 normal;
 } vs_out;
 
 uniform mat4 view;
 uniform mat4 model;
 
 void main()
 {
     gl_Position = view * model * vec4(aPos, 1.0); 
     mat3 normalMatrix = mat3(transpose(inverse(view * model)));
     vs_out.normal = normalize(vec3(vec4(normalMatrix * aNormal, 0.0)));
 }
 </code></pre>
 
 <p>
   The transformed view-space normal vector is then passed to the next shader stage via an interface block. The geometry shader then takes each vertex (with a position and a normal vector) and draws a normal vector from each position vector:
 </p>
 
 <pre><code>
 #version 330 core
 layout (triangles) in;
 layout (line_strip, max_vertices = 6) out;
 
 in VS_OUT {
     vec3 normal;
 } gs_in[];
 
 const float MAGNITUDE = 0.4;
   
 uniform mat4 projection;
 
 void GenerateLine(int index)
 {
     gl_Position = projection * gl_in[index].gl_Position;
     EmitVertex();
     gl_Position = projection * (gl_in[index].gl_Position + 
                                 vec4(gs_in[index].normal, 0.0) * MAGNITUDE);
     EmitVertex();
     EndPrimitive();
 }
 
 void main()
 {
     GenerateLine(0); // first vertex normal
     GenerateLine(1); // second vertex normal
     GenerateLine(2); // third vertex normal
 }  
 </code></pre>
 
 <p>
   The contents of geometry shaders like these should be self-explanatory by now. Note that we're multiplying the normal vector by a <var>MAGNITUDE</var> vector to restrain the size of the displayed normal vectors (otherwise they'd be a bit too large). 
 </p>
 
 <p>
   Since visualizing normals are mostly used for debugging purposes we can just display them as mono-colored lines (or super-fancy lines if you feel like it) with the help of the fragment shader:
 </p>
 
 <pre><code>
 #version 330 core
 out vec4 FragColor;
 
 void main()
 {
     FragColor = vec4(1.0, 1.0, 0.0, 1.0);
 }  
 </code></pre>
 
 <p>
   Now rendering your model with normal shaders first and then with the special <em>normal-visualizing</em> shader you'll see something like this:
 </p>
 
 <img src="/img/advanced/geometry_shader_normals.png" class="clean" alt="Image of geometry shader displaying normal vectors in OpenGL"/>
 
 <p>
   Apart from the fact that our backpack now looks a bit hairy, it gives us a really useful method for determining if the normal vectors of a model are indeed correct. You can imagine that geometry shaders like this could also be used for adding <def>fur</def> to objects.
 </p>
 
 <p>
   You can find the OpenGL's source code <a href="/code_viewer_gh.php?code=src/4.advanced_opengl/9.3.geometry_shader_normals/normal_visualization.cpp" target="_blank">here</a>.
 </p>       
 
     </div>